summaryrefslogtreecommitdiff
path: root/libwatchfish.pri
blob: 24a3c669d6360bc6c9591449a0c181e65ea457bd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
CONFIG += link_pkgconfig

contains(WATCHFISH_FEATURES, notificationmonitor) {
	PKGCONFIG += dbus-1
	HEADERS += $$PWD/notificationmonitor.h $$PWD/notificationmonitor_p.h $$PWD/notification.h
	SOURCES += $$PWD/notificationmonitor.cpp $$PWD/notification.cpp
}

contains(WATCHFISH_FEATURES, walltime) {
	PKGCONFIG += timed-qt5
	HEADERS += $$PWD/walltimemonitor.h $$PWD/walltimemonitor_p.h
	SOURCES += $$PWD/walltimemonitor.cpp
}

contains(WATCHFISH_FEATURES, music) {
	PKGCONFIG += mpris-qt5
	HEADERS += $$PWD/musiccontroller.h $$PWD/musiccontroller_p.h $$PWD/volumecontroller.h
	SOURCES += $$PWD/musiccontroller.cpp $$PWD/volumecontroller.cpp
	DBUS_INTERFACES += com.Meego.MainVolume2.xml
}

contains(WATCHFISH_FEATURES, calendar) {
	PKGCONFIG += libmkcal-qt5 libkcalcoren-qt5
	HEADERS += $$PWD/calendarsource.h $$PWD/calendarsource_p.h $$PWD/calendarevent.h
	SOURCES += $$PWD/calendarsource.cpp $$PWD/calendarevent.cpp
}

contains(WATCHFISH_FEATURES, voicecall) {
	HEADERS += $$PWD/voicecallcontroller.h $$PWD/voicecallcontroller_p.h
	SOURCES += $$PWD/voicecallcontroller.cpp
	DBUS_INTERFACES += org.nemomobile.voicecall.VoiceCallManager.xml org.nemomobile.voicecall.VoiceCall.xml
}

HEADERS += \
    $$PWD/volumecontroller_p.h

DISTFILES += \
    $$PWD/com.Meego.MainVolume2.xml