TARGET = sapd
TEMPLATE = app
QT       += core gui dbus
CONFIG   += console

CONFIG    += link_pkgconfig
PKGCONFIG += openssl

exists(/usr/lib/libsailfishapp.so) {
    # Building for Jolla Sailfish, Qt5, Bluez5
    QT       += bluetooth
    DEFINES  += SAILFISH
    DBUS_ADAPTORS += sailfish/org.freedesktop.Notifications.xml
    SOURCES  += sailfish/notificationmonitor.cpp
    HEADERS  += sailfish/notificationmonitor.h
} else:greaterThan(QT_MAJOR_VERSION, 4) {
    # Building for desktop, Qt5, Bluez5
    QT       += bluetooth
    DEFINES  += DESKTOP
    SOURCES  += hfpag.cc
    HEADERS  += hfpag.h
} else {
    # Building for desktop, Qt4, Bluez5
    CONFIG   += mobility
    MOBILITY += connectivity
    DEFINES  += DESKTOP MANUAL_SDP
    SOURCES  += hfpag.cc
    HEADERS  += hfpag.h
    PKGCONFIG += bluez
}

target.path = /usr/bin
INSTALLS += target

SOURCES += main.cc \
    sapbtlistener.cc \
    wmspeer.cc \
    sapbtpeer.cc \
    saprotocol.cc \
    keys/Tout.c \
    keys/Tin.c \
    keys/T2.c \
    keys/T1.c \
    keys/T0.c \
    keys/psk_table.c \
    keys/finalT1.c \
    keys/finalT0.c \
    keys/DecTout.c \
    keys/DecTin.c \
    keys/DecT2.c \
    keys/DecT1.c \
    keys/DecT0.c \
    wmscrypt.cc \
    crc16.cc \
    sapsocket.cc \
    sappeer.cc \
    capabilityagent.cc \
    qtjson/json.cc \
    sapmanager.cc \
    sapserviceinfo.cc \
    sapchannelinfo.cc \
    sapconnection.cc \
    sapconnectionrequest.cc \
    capabilitypeer.cc \
    hostmanageragent.cc \
    hostmanagerconn.cc \
    notificationagent.cc \
    notificationconn.cc

HEADERS += \
    sapbtlistener.h \
    wmspeer.h \
    sapbtpeer.h \
    saprotocol.h \
    wmskeys.h \
    wmscrypt.h \
    crc16.h \
    sapsocket.h \
    sapagent.h \
    sappeer.h \
    capabilityagent.h \
    qtjson/json.h \
    sapmanager.h \
    sapserviceinfo.h \
    sapchannelinfo.h \
    sapconnection.h \
    sapconnectionrequest.h \
    capabilitypeer.h \
    hostmanageragent.h \
    hostmanagerconn.h \
    notificationagent.h \
    notificationconn.h \
    endianhelpers.h

OTHER_FILES += \
    rpm/sapd.yaml \
    sailfish/org.freedesktop.Notifications.xml