TARGET = sapd
TEMPLATE = app
QT       += core gui dbus network bluetooth
CONFIG   += console c++11

CONFIG    += link_pkgconfig
PKGCONFIG += openssl

exists(/usr/lib/pkgconfig/sailfishapp.pc) {
    # Building for Jolla Sailfish, Qt5, Bluez4(?)
    DEFINES  += SAILFISH
    PKGCONFIG += dbus-1 timed-qt5 bluez-qt5 mpris-qt5
    SOURCES  += libwatchfish/notificationmonitor.cpp libwatchfish/notification.cpp \
        libwatchfish/walltimemonitor.cpp \
        libwatchfish/musiccontroller.cpp
    HEADERS  += libwatchfish/notificationmonitor.h libwatchfish/notificationmonitor_p.h libwatchfish/notification.h \
        libwatchfish/walltimemonitor.h libwatchfish/walltimemonitor_p.h \
        libwatchfish/musiccontroller.h libwatchfish/musiccontroller_p.h
} else {
    # Building for desktop, Qt5, Bluez5
    DEFINES  += DESKTOP
    SOURCES  += hfpag.cc
    HEADERS  += hfpag.h
}

target.path = /usr/bin
INSTALLS += target

SOURCES += main.cc \
    sapbtlistener.cc \
    wmspeer.cc \
    sapbtpeer.cc \
    saprotocol.cc \
    keys/Tout.c \
    keys/Tin.c \
    keys/T2.c \
    keys/T1.c \
    keys/T0.c \
    keys/psk_table.c \
    keys/finalT1.c \
    keys/finalT0.c \
    keys/DecTout.c \
    keys/DecTin.c \
    keys/DecT2.c \
    keys/DecT1.c \
    keys/DecT0.c \
    wmscrypt.cc \
    crc16.cc \
    sapsocket.cc \
    sappeer.cc \
    capabilityagent.cc \
    sapmanager.cc \
    sapserviceinfo.cc \
    sapchannelinfo.cc \
    sapconnection.cc \
    sapconnectionrequest.cc \
    capabilitypeer.cc \
    hostmanageragent.cc \
    hostmanagerconn.cc \
    notificationagent.cc \
    notificationconn.cc \
    webproxyagent.cc \
    webproxyconn.cc \
    webproxytrans.cc \
    musicagent.cc \
    musicconn.cc

HEADERS += \
    sapbtlistener.h \
    wmspeer.h \
    sapbtpeer.h \
    saprotocol.h \
    wmskeys.h \
    wmscrypt.h \
    crc16.h \
    sapsocket.h \
    sapagent.h \
    sappeer.h \
    capabilityagent.h \
    sapmanager.h \
    sapserviceinfo.h \
    sapchannelinfo.h \
    sapconnection.h \
    sapconnectionrequest.h \
    capabilitypeer.h \
    hostmanageragent.h \
    hostmanagerconn.h \
    notificationagent.h \
    notificationconn.h \
    endianhelpers.h \
    webproxyagent.h \
    webproxyconn.h \
    webproxytrans.h \
    musicagent.h \
    musicconn.h

OTHER_FILES += \
    rpm/sapd.yaml \
    sailfish/org.freedesktop.Notifications.xml