QT       += core gui svg phonon

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = scribiu
TEMPLATE = app

CONFIG += link_pkgconfig
PKGCONFIG += libudev libusb openobex
LIBS += -lquazip

SOURCES += main.cc\
        mainwindow.cc \
    smartpenmanager.cc \
    notebookmodel.cc \
    smartpensyncer.cc \
    smartpen.cc bitreader.cc stfreader.cc \
    xmlutils.cc \
    notebookview.cc \
    afdnotebook.cc \
    pageitem.cc \
    stfgraphicsitem.cc \
    paperreplay.cc \
    afdpageaddress.cc \
    stfstrokeitem.cc \
    paperreplaymodel.cc

HEADERS  += mainwindow.h \
    smartpenmanager.h \
    notebookmodel.h \
    smartpensyncer.h \
    smartpen.h bitreader.h stfreader.h \
    xmlutils.h \
    notebookview.h \
    afdnotebook.h \
    pageitem.h \
    stfgraphicsitem.h \
    paperreplay.h \
    afdpageaddress.h \
    stfstrokeitem.h \
    paperreplaymodel.h

FORMS    += mainwindow.ui

isEmpty(PREFIX) {
	PREFIX = /usr
}

target.path = $$PREFIX/bin

icon.path = $$PREFIX/share/icons/hicolor/scalable/apps
icon.files = scribiu.svg

desktop.path = $$PREFIX/share/applications
desktop.files = scribiu.desktop

INSTALLS += target icon desktop