aboutsummaryrefslogtreecommitdiff
path: root/scribiu.pro
blob: cca4eefc112181cb919f02556228a37cf795260a (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
TARGET = scribiu
TEMPLATE = app

QT       += core gui widgets svg
QT       += phonon4qt5

CONFIG += c++11

CONFIG += link_pkgconfig
PKGCONFIG += libudev libusb-1.0 openobex quazip

SOURCES += main.cc \
    mainwindow.cc \
    smartpenmanager.cc \
    notebookmodel.cc \
    smartpensyncer.cc \
    smartpen.cc bitreader.cc stfreader.cc \
    xmlutils.cc \
    notebookview.cc \
    afdnotebook.cc \
    pageitem.cc \
    stfgraphicsitem.cc \
    paperreplay.cc \
    afdpageaddress.cc \
    stfstrokeitem.cc \
    paperreplaymodel.cc

HEADERS  += mainwindow.h \
    smartpenmanager.h \
    notebookmodel.h \
    smartpensyncer.h \
    smartpen.h bitreader.h stfreader.h \
    xmlutils.h \
    notebookview.h \
    afdnotebook.h \
    pageitem.h \
    stfgraphicsitem.h \
    paperreplay.h \
    afdpageaddress.h \
    stfstrokeitem.h \
    paperreplaymodel.h

FORMS    += mainwindow.ui

isEmpty(PREFIX) {
	PREFIX = /usr
}

isEmpty(UDEVDIR) {
        UDEVDIR = $$system(pkg-config --variable=udevdir udev)
}

target.path = $$PREFIX/bin

udev.path = $$UDEVDIR/rules.d
udev.files = 60-livescribe.rules

icon_scalable.path = $$PREFIX/share/icons/hicolor/scalable/apps
icon_scalable.files = icons/scalable/scribiu.svg

icon_48.path = $$PREFIX/share/icons/hicolor/48x48/apps
icon_48.files = icons/48x48/scribiu.png

desktop.path = $$PREFIX/share/applications
desktop.files = scribiu.desktop

INSTALLS += target udev icon_scalable icon_48 desktop

OTHER_FILES = icons/inkscape/scribiu.svg README.md COPYING